add fonts module and use that instead

home/common/desktop/default.nix

@@ -3,6 +3,7 @@
     ./font.nix
     ./firefox.nix
     ./kitty.nix
+    ./gtk.nix
   ];
 
   home.packages = with pkgs; [

home/common/desktop/font.nix

@@ -1,8 +1,13 @@
 { imports, config, pkgs, ... }: {
-  home.packages = with pkgs; [
+  fontProfiles = {
-    noto-fonts
+    enable = true;
-    noto-fonts-emoji
+    monospace = {
-  ];
+      family = "JetBrains Mono Nerd Font";
-
+      package = pkgs.nerdfonts.override { fonts = ["JetBrainsMono"]; };
-  fonts.fontconfig.enable = true;
+    };
+    regular = {
+      family = "Fira Sans";
+      package = pkgs.fira;
+    };
+  };
 }

home/common/desktop/gtk.nix

@@ -0,0 +1,10 @@
+{ config, pkgs, inputs, lib, ... }: {
+  gtk = {
+    enable = true;
+    font = {
+      name = config.fontProfiles.regular.family;
+      package = config.fontProfiles.regular.package;
+      size = 12;
+    };
+  };
+}

modules/home-manager/default.nix

@@ -1,3 +1,4 @@
 {
   monitors = import ./monitors.nix;
+  fonts = import ./fonts.nix;
 }

modules/home-manager/fonts.nix

@@ -0,0 +1,35 @@
+{
+  lib,
+  config,
+  ...
+}: let
+  mkFontOption = kind: {
+    family = lib.mkOption {
+      type = lib.types.str;
+      default = null;
+      description = "Family name for ${kind} font profile";
+      example = "Fira Code";
+    };
+    package = lib.mkOption {
+      type = lib.types.package;
+      default = null;
+      description = "Package for ${kind} font profile";
+      example = "pkgs.fira-code";
+    };
+  };
+  cfg = config.fontProfiles;
+in {
+  options.fontProfiles = {
+    enable = lib.mkEnableOption "Whether to enable font profiles";
+    monospace = mkFontOption "monospace";
+    regular = mkFontOption "regular";
+  };
+
+  config = lib.mkIf cfg.enable {
+    fonts.fontconfig.enable = true;
+    home.packages = [
+      cfg.monospace.package
+      cfg.regular.package
+    ];
+  };
+}